%# BEGIN BPS TAGGED BLOCK {{{
%# 
%# COPYRIGHT:
%# 
%# This software is Copyright (c) 1996-2009 Best Practical Solutions, LLC
%#                                          <jesse@bestpractical.com>
%# 
%# (Except where explicitly superseded by other copyright notices)
%# 
%# 
%# LICENSE:
%# 
%# This work is made available to you under the terms of Version 2 of
%# the GNU General Public License. A copy of that license should have
%# been provided with this software, but in any event can be snarfed
%# from www.gnu.org.
%# 
%# This work is distributed in the hope that it will be useful, but
%# WITHOUT ANY WARRANTY; without even the implied warranty of
%# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
%# General Public License for more details.
%# 
%# You should have received a copy of the GNU General Public License
%# along with this program; if not, write to the Free Software
%# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
%# 02110-1301 or visit their web page on the internet at
%# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
%# 
%# 
%# CONTRIBUTION SUBMISSION POLICY:
%# 
%# (The following paragraph is not intended to limit the rights granted
%# to you to modify and distribute this software under the terms of
%# the GNU General Public License and is only of importance to you if
%# you choose to contribute your changes and enhancements to the
%# community by submitting them to Best Practical Solutions, LLC.)
%# 
%# By intentionally submitting any modifications, corrections or
%# derivatives to this work, or any other work intended for use with
%# Request Tracker, to Best Practical Solutions, LLC, you confirm that
%# you are the copyright holder for those contributions and you grant
%# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
%# royalty-free, perpetual, license to use, copy, create derivative
%# works based on those contributions, and sublicense and distribute
%# those contributions and any derivatives thereof.
%# 
%# END BPS TAGGED BLOCK }}}
%# REST/1.0/Forms/ticket/comment
%#
<%ARGS>
$id
%changes
</%ARGS> 
<%INIT>
use MIME::Entity;
use LWP::MediaTypes;
use RT::Interface::REST;
use File::Temp qw(tempfile);

$RT::Logger->debug("Got ticket id=$id for comment");
$RT::Logger->debug("Got args @{[keys(%changes)]}.");

my $ticket = new RT::Ticket $session{CurrentUser};
my ($c, $o, $k, $e) = ("", [], {}, 0);

# http://.../REST/1.0/ticket/1/comment
$ticket->Load($id);
if (!$ticket->Id) {
    $e = 1;
    $c = "# Ticket $id does not exist.";
    goto OUTPUT;
}

my $action;
($action = $changes{Action}) =~ s/^(.)(.*)$/\U$1\L$2\E/;
unless ($action =~ /^(?:Comment|Correspond)$/) {
    $e = 1;
    $c = "# Invalid action: `$action'.";
    goto OUTPUT;
}

my $text = $changes{Text};
my @atts = @{ vsplit($changes{Attachment}) };

if (!$changes{Text} && @atts == 0) {
    $e = 1;
    $c = "# Empty comment with no attachments submitted.";
    goto OUTPUT;
}

my $cgi = $m->cgi_object;
my $ent = MIME::Entity->build(Type => "multipart/mixed");
$ent->attach(Data => $changes{Text}) if $changes{Text};

my $i = 1;
foreach my $att (@atts) {
    local $/=undef;
    my $file = $att;
    $file =~ s#^.*[\\/]##;

    my $fh = $cgi->upload("attachment_$i");
    if ($fh) {
        my $buf;
        my ($w, $tmp) = tempfile();
        my $info = $cgi->uploadInfo($fh);

        while (sysread($fh, $buf, 8192)) {
            syswrite($w, $buf);
        }

        $ent->attach(
            Path => $tmp,
            Type => $info->{'Content-Type'} || guess_media_type($tmp),
            Filename => $file,
            Disposition => "attachment"
        );
    }
    else {
        $e = 1;
        $c = "# No attachment for $att.";
        goto OUTPUT;
    }

    $i++;
}

unless ($ticket->CurrentUserHasRight('ModifyTicket') ||
        ($action eq "Comment" &&
         $ticket->CurrentUserHasRight("CommentOnTicket")) ||
        ($action eq "Correspond" &&
         $ticket->CurrentUserHasRight("ReplyToTicket")))
{
    $e = 1;
    $c = "# You are not allowed to $action on ticket $id.";
    goto OUTPUT;
}

my $cc = join ", ", @{ vsplit($changes{Cc}) };
my $bcc = join ", ", @{ vsplit($changes{Bcc}) };
my ($n, $s) = $ticket->$action(MIMEObj => $ent,
                               CcMessageTo => $cc,
                               BccMessageTo => $bcc,
                               TimeTaken => $changes{TimeWorked} || 0);
$c = "# ".$s;
if ($changes{Status}) {
   my  ($status_n, $status_s) = $ticket->SetStatus($changes{'Status'} );   
  $c .= "\n# ".$status_s;
}

OUTPUT:
return [ $c, $o, $k, $e ];
</%INIT>
