Qt 4.8: calculator.qml Example File (demos/declarative/calculator/qml/calculator/calculator.qml)

Qt Reference Documentation

# calculator.qml Example File

demos/declarative/calculator/qml/calculator/calculator.qml

     /****************************************************************************
     **
     ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
     ** All rights reserved.
     ** Contact: Nokia Corporation (qt-info@nokia.com)
     **
     ** This file is part of the QtDeclarative module of the Qt Toolkit.
     **
     ** $QT_BEGIN_LICENSE:LGPL$
     ** GNU Lesser General Public License Usage
     ** This file may be used under the terms of the GNU Lesser General Public
     ** License version 2.1 as published by the Free Software Foundation and
     ** appearing in the file LICENSE.LGPL included in the packaging of this
     ** file. Please review the following information to ensure the GNU Lesser
     ** General Public License version 2.1 requirements will be met:
     ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
     **
     ** In addition, as a special exception, Nokia gives you certain additional
     ** rights. These rights are described in the Nokia Qt LGPL Exception
     ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
     **
     ** GNU General Public License Usage
     ** Alternatively, this file may be used under the terms of the GNU General
     ** Public License version 3.0 as published by the Free Software Foundation
     ** and appearing in the file LICENSE.GPL included in the packaging of this
     ** file. Please review the following information to ensure the GNU General
     ** Public License version 3.0 requirements will be met:
     ** http://www.gnu.org/copyleft/gpl.html.
     **
     ** Other Usage
     ** Alternatively, this file may be used in accordance with the terms and
     ** conditions contained in a signed written agreement between you and Nokia.
     **
     **
     **
     **
     **
     ** $QT_END_LICENSE$
     **
     ****************************************************************************/

     import QtQuick 1.0
     import "CalculatorCore"
     import "CalculatorCore/calculator.js" as CalcEngine

     Rectangle {
         id: window

         width: 360; height: 480
         color: "#282828"

         property string rotateLeft: "\u2939"
         property string rotateRight: "\u2935"
         property string leftArrow: "\u2190"
         property string division : "\u00f7"
         property string multiplication : "\u00d7"
         property string squareRoot : "\u221a"
         property string plusminus : "\u00b1"

         function doOp(operation) { CalcEngine.doOperation(operation) }

         Item {
             id: main
             state: "orientation " + runtime.orientation

             property bool landscapeWindow: window.width > window.height
             property real baseWidth: landscapeWindow ? window.height : window.width
             property real baseHeight: landscapeWindow ? window.width : window.height
             property real rotationDelta: landscapeWindow ? -90 : 0

             rotation: rotationDelta
             width: main.baseWidth
             height: main.baseHeight
             anchors.centerIn: parent

             Column {
                 id: box; spacing: 8

                 anchors { fill: parent; topMargin: 6; bottomMargin: 6; leftMargin: 6; rightMargin: 6 }

                 Display {
                     id: display
                     width: box.width-3
                     height: 64
                 }

                 Column {
                     id: column; spacing: 6

                     property real h: ((box.height - 72) / 6) - ((spacing * (6 - 1)) / 6)
                     property real w: (box.width / 4) - ((spacing * (4 - 1)) / 4)

                     Row {
                         spacing: 6
                         Button { width: column.w; height: column.h; color: 'purple'; operation: "Off" }
                         Button { width: column.w; height: column.h; color: 'purple'; operation: leftArrow }
                         Button { width: column.w; height: column.h; color: 'purple'; operation: "C" }
                         Button { width: column.w; height: column.h; color: 'purple'; operation: "AC" }
                     }

                     Row {
                         spacing: 6
                         property real w: (box.width / 4) - ((spacing * (4 - 1)) / 4)

                         Button { width: column.w; height: column.h; color: 'green'; operation: "mc" }
                         Button { width: column.w; height: column.h; color: 'green'; operation: "m+" }
                         Button { width: column.w; height: column.h; color: 'green'; operation: "m-" }
                         Button { width: column.w; height: column.h; color: 'green'; operation: "mr" }
                     }

                     Grid {
                         id: grid; rows: 5; columns: 5; spacing: 6

                         property real w: (box.width / columns) - ((spacing * (columns - 1)) / columns)

                         Button { width: grid.w; height: column.h; operation: "7"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "8"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "9"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: division }
                         Button { width: grid.w; height: column.h; operation: squareRoot }
                         Button { width: grid.w; height: column.h; operation: "4"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "5"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "6"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: multiplication }
                         Button { width: grid.w; height: column.h; operation: "x^2" }
                         Button { width: grid.w; height: column.h; operation: "1"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "2"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "3"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "-" }
                         Button { width: grid.w; height: column.h; operation: "1/x" }
                         Button { width: grid.w; height: column.h; operation: "0"; color: 'blue' }
                         Button { width: grid.w; height: column.h; operation: "." }
                         Button { width: grid.w; height: column.h; operation: plusminus }
                         Button { width: grid.w; height: column.h; operation: "+" }
                         Button { width: grid.w; height: column.h; operation: "="; color: 'red' }
                     }
                 }
             }

             states: [
                 State {
                     name: "orientation " + Orientation.Landscape
                     PropertyChanges { target: main; rotation: 90 + rotationDelta; width: main.baseHeight; height: main.baseWidth }
                 },
                 State {
                     name: "orientation " + Orientation.PortraitInverted
                     PropertyChanges { target: main; rotation: 180 + rotationDelta; }
                 },
                 State {
                     name: "orientation " + Orientation.LandscapeInverted
                     PropertyChanges { target: main; rotation: 270 + rotationDelta; width: main.baseHeight; height: main.baseWidth }
                 }
             ]

             transitions: Transition {
                 SequentialAnimation {
                     RotationAnimation { direction: RotationAnimation.Shortest; duration: 300; easing.type: Easing.InOutQuint  }
                     NumberAnimation { properties: "x,y,width,height"; duration: 300; easing.type: Easing.InOutQuint }
                 }
             }
         }
     }